How to get Form's caller in Dynamics AX?

-

Hello readers,

In Dynamics AX, when we need to find the parent of a form, we call the caller() method on the args object of the formRun object of the form. The syntax is,

FormRun callerForm = element.args().caller();

In the same way, we can find the parent of the caller form as well.
Something like,

FormRun callerForm = element.args().caller().args().caller();

Try that and Dynamics AX will throw an error that "The variable is not of the type CLASS."

We can call only upto the 3rd method after which the AX compiler fails to return an object.

We will have to first store the args() object in a seperate variable and then call the caller() method.

Let us look at an example of getting all the ancestors for a form.

I've a simple form, with just two methods - init() and parmFormName()

Declare a variable formName of type Name in the classDeclaration.

public Name parmFormName(Name _formName = formName)
{
    formName = _formName;

    return formName;
}

public void init()
{
    Object  caller;    
    Args    args;

    super();

    info(element.parmFormName());

    caller = element.args().caller();

    while (caller)
    {

        info(caller.parmFormName());
        args = caller.args();
        caller = args.caller();
    }
}
Thats the form. No extra design. Just a plain vanilla form.

Now I'll call this form from a job, but only after ensuring it has a great grand parent.
static void callForm(Args _args)
{
    Args        args;
    Object      formRun;
    int i;

    args = new Args(formStr(SampleForm));
    formRun = classFactory.formRunClass(args);
    if (formHasMethod(formRun, identifierStr(parmFormName)))
    {
        formRun.parmFormName("Form number 1");
    }

    for (i=2; i<=4; i++)
    {
        args = new Args(formStr(SampleForm));
        
		// Set the form's caller or parent
		args.caller(formRun);
        formRun = classFactory.formRunClass(args);
        
		// It is a best practice to first check if the method exists on the form before calling it.
		if (formHasMethod(formRun, identifierStr(parmFormName)))
        {
            // Sets the form's name variable
			formRun.parmFormName(strFmt("Form number %1",i));
        }
    }

    formRun.run();    
}
What I have done is first initialized a formRun object for our SampleForm. Next I'm running a loop 3 times to create three more instances of SampleForm and setting the form's parent to the previous instance. Then I run the form. Lets run the job now. Here is the output.
Dynamics AX infolog
The code in the SampleForm's init() method iterates through the callers until it reaches the first instance of the form. It calls the parmFormName() method on the form to print the form's name. The order is Form 4 is child of Form 3, Form 3 is child of Form 2 and Form 2 is the child of Form 1.
Dynamics AX caller form
When calling methods on forms or classes, using their generic form like formRun, always declare the variable as Object. This way you will not get a compilation error. Ofcourse, it is the developer's responsibility to ensure that there is no runtime error as well. For this purpose, use the intrinsic method formHasMethod() to make sure that the method indeed exists on the form. If you do not perform this check, and the method has been deleted or renamed, then you will recieve a runtime error. I hope this post was helpful. Please feel free to send me your questions, comments or any feedback using the Contact me form. You can download the project used from here.

Thats all for today folks, but do check back soon as we continue to learn more.

Popular posts from this blog

How to add empty ranges in query

-
In Dynamics AX programming, a common mistake I have seen when it comes to query ranges is passing an empty string value to the range. The developer here is expecting it to show all the records where the range field is empty. Instead, what we get is all records without the range being applied. As baffling as it may seems, it is easily explainable. The query engine in Dynamics AX, will not add a range if you don’t specify a value or if you specify an empty string because an empty string is treated as no value. So the following code will result in this SQL statement, query = new Query(); qbds = query.addDataSource(tableNum(ProjTable)); qbr = qbds.addRange(fieldNum(ProjTable, Name)); qbr.value(''); Select first fast * from ProjTable; But what was expected was something like, Select first fast * from ProjTable where Name == ''; So to work around this issue, use the SysQuery::valueEmptyString() static method which parses the empty strings correctly so that it...
Read more

The field with ID '0' does not exist in table - Cause and resolution.

-
Image
Hello readers, In Dynamics AX coding, you should have come across this error sometime - The field with ID '0' does not exist in table 'SomeTable' So what causes this error and what is the possible resolution to it? Well, the most likely cause for this error is a missing mapping in a table map. Let us look at an example. I've a simple Map named CustVendAccount with one Account field. I've created two mappings - one with CustTable's AccountNum field and for the otehr mapping, I just specify VendTable but no field. This is how my map looks like, Now, I've a simple job which just passes either CustTable or VendTable as an argument and then we print the Account field in the map. static void CustVendAccountMap(Args _args) { CustTable custTable; VendTable vendTable; void readMap(CustVendAccount _custVendAccount) { info(strFmt("Value from table %1 is %2",tableId2name(_custVendAccount.TableId), _custV...
Read more

Get selected records in Dynamics AX 2012

-
Image
In my earlier post, we discussed how we can retrieve all selected records on a list page. You can read that post here . Retrieving all selected records from a caller form is very easy. The code for this can be found in a number of places in standard Dynamics AX codebase. The general approach is to use the dataSource.getFirst(1) statement to get the first selected record and loop through the remaining using dataSource.getNext() . In Dynamics AX 2009, a new class was introduced for this purpose. This was the MultiSelectionHelper class. In Dynamics AX 2012, another new class has been introduced to retrieve the selected records. This is the MultiSelectionContext class. The MultiSelectionHelper class is an application class. It presents two constrcutors. The standard constructor method just creates a new instance of the MultiSelectionHelper class. When this construct is used, you will have to explicitly set the dataSource to be used for fethcing selected records. This can be done...
Read more